Ankündigung

Einklappen
Keine Ankündigung bisher.

Vsio - Rolläden verhält sich unterschiedlich

Einklappen
X
 
  • Filter
  • Zeit
  • Anzeigen
Alles löschen
neue Beiträge

    Vsio - Rolläden verhält sich unterschiedlich

    Hallo zusammen,

    nach ganz langer Zeit habe ich mich mal wieder an eine Ergänzung gemacht.
    Velux Rolläden für Dachflächenfenster mittels Jalo-Aktor integriert.
    Grundsätzlich läuft das auch.
    Allerdings verhält sich die Visio bei der Statusanzeige nicht so wie bei meinen anderen Bestands-Rollöden.


    Bestands-Rolladen:

    Code:
    //Rollo Essen
    if pbutton(6,4)==1 then {
    write("Küche/Essen Rolläden-5/0/12",AUS)
    } endif
    if pbutton(6,4)==3 then {
    write("Küche/Essen Rolläden-5/0/12",EIN)
    } endif
    if pbutton(6,4)==2 then {
    write("Küche/Essen Rolläden - Lamelle-5/0/13",EIN)
    } endif
    
    if event("Küche/Essen Rolläden-5/0/12") then {
    pdisplay(6,$Rollo fährt$,STOP,DARKRED,GREY,4)
    } endif
    
    a=0
    // Rollo fährt runter
    if event("Küche/Essen Rolläden-5/0/12") and ("Küche/Essen Rolläden-5/0/12"==EIN) then a=a+1 endif
    // Rollo wird beim Runterfahren angehalten
    if event("Küche/Essen Rolläden - Lamelle-5/0/13") and ("Küche/Essen Rolläden-5/0/12"==EIN) then {
    pdisplay(6,$noch nicht unten$,BLIND,ACTIVE,GREY,4);
    a=0
    } endif
    // Rollo nach 30000ms auf Endanschlag unten
    if after(a==1, 30000u64) and a==1 then {
    pdisplay(6,$Unten$,BLIND,INACTIVE,GREY,4);
    a=0
    } endif
    // Rollo fährt hoch
    if event("Küche/Essen Rolläden-5/0/12") and ("Küche/Essen Rolläden-5/0/12"==AUS) then a=a+10 endif
    // Rollo wird beim Hochfahren angehalten
    if event("Küche/Essen Rolläden - Lamelle-5/0/13") and ("Küche/Essen Rolläden-5/0/12"==AUS) then {
    pdisplay(6,$noch nicht oben$,BLIND,INACTIVE,GREY,4);
    a=0
    } endif
    // Rollo nach 30000ms auf Endanschlaug oben
    if after(a==10, 30000u64) and a==10 then {
    pdisplay(6,$Oben$,BLIND,ACTIVE,GREY,4);
    a=0
    } endif

    Neuer Rolladen Dachfläche

    Code:
    //Rollo Dach Ankleide
    if pbutton(14,2)==1 then {
    write("Dach Ankleide-5/3/0",AUS)
    } endif
    if pbutton(14,2)==3 then {
    write("Dach Ankleide-5/3/0",EIN)
    } endif
    if pbutton(14,2)==2 then {
    write("Dach Ankleide Stop-5/3/3",EIN)
    } endif
    
    if event("Dach Ankleide-5/3/0") then {
    pdisplay(14,$Rollo fährt$,STOP,DARKRED,GREY,4)
    } endif
    
    g=0
    // Rollo fährt runter
    if event("Dach Ankleide-5/3/0") and ("Dach Ankleide-5/3/0"==EIN) then g=g+1 endif
    // Rollo wird beim Runterfahren angehalten
    if event("Dach Ankleide Stop-5/3/3") and ("Dach Ankleide-5/3/0"==EIN) then {
    pdisplay(14,$noch nicht unten$,BLIND,ACTIVE,GREY,4);
    g=0
    } endif
    // Rollo nach 45000ms auf Endanschlag unten
    if after(g==1, 45000u64) and g==1 then {
    pdisplay(14,$Unten$,BLIND,INACTIVE,GREY,4);
    g=0
    } endif
    // Rollo fährt hoch
    if event("Dach Ankleide-5/3/0") and ("Dach Ankleide-5/3/0"==AUS) then g=g+10 endif
    // Rollo wird beim Hochfahren angehalten
    if event("Dach Ankleide Stop-5/3/3") and ("Dach Ankleide-5/3/0"==AUS) then {
    pdisplay(14,$noch nicht oben$,BLIND,INACTIVE,GREY,4);
    g=0
    } endif
    // Rollo nach 45000ms auf Endanschlaug oben
    if after(g==10, 45000u64) and g==10 then {
    pdisplay(14,$Oben$,BLIND,ACTIVE,GREY,4);
    g=0
    } endif
    Für mich sieht alles gleich aus.
    Jedoch zeigt mir die neue Viso Anzeige nichts an.
    Keinen Status "Hoch", "Runter" und auch keinen "Stop".
    Auch wird der mittlere Button nicht "rot" beim fahren.

    Zur Info, ich setze aktuell noch die EibStudio Version 3.204 ein.
    Bisher gab es auch keine Anforderung für einen Update.
    Das System läuft sonst super.

    Ich hoffe jemand hat eine Idee.

    Vielen Dank im Voraus und beste Grüße
    Jens

    #2
    Passt die ID für das Objekt (14) und die Seite (4)?
    Code sieht auf den ersten Blick ok aus.
    was sagt der debugger?

    Tipp
    statt ein/aus geht auch rauf/runter. Liest sich bei Rollo logischer.
    ....und versuchen Sie nicht erst anhand der Farbe der Stichflamme zu erkennen, was Sie falsch gemacht haben!

    Kommentar


      #3
      Ja, die IDs passen.
      //Pages
      BeleuchtungEGPageID = 1
      BeleuchtungOGSTPageID = 2
      AussenPageID = 3
      ZentralPageID = 4
      PVPageID = 5
      WeatherPageID = 6

      //OG_Studio
      ...
      RolloAnkleideID = 14
      RolloBadID = 15
      RolloStudioID = 16

      //Zentral
      RolloEssenID = 6
      RolloSuedID = 7
      RolloTerrasseID = 8
      RolloOstID = 9
      RolloSchlafenID = 10
      RolloAlleID = 11

      Wie gesagt, meine Rollos unter Page ID 4 laufen seit Jahren super.


      Die Meldungen sehen für mich auch gut aus.
      Ablauf jeweils:
      Runter (Ein) / Stopp / Hoch (Aus)

      Code:
      % 2020-06-14 11:47:21 | Sender: EibPC | GA: "Küche/Essen Rolläden-5/0/12" | Wert: EIN | Typ: Binärwert | Schreiben
      % 2020-06-14 11:47:26 | Sender: EibPC | GA: "Küche/Essen Rolläden - Lamelle-5/0/13" | Wert: EIN | Typ: Binärwert | Schreiben
      % 2020-06-14 11:47:29 | Sender: EibPC | GA: "Küche/Essen Rolläden-5/0/12" | Wert: AUS | Typ: Binärwert | Schreiben
      
      % 2020-06-14 11:47:41 | Sender: EibPC | GA: "Dach Ankleide-5/3/0" | Wert: EIN | Typ: Binärwert | Schreiben
      % 2020-06-14 11:47:46 | Sender: EibPC | GA: "Dach Ankleide Stop-5/3/3" | Wert: EIN | Typ: Binärwert | Schreiben
      % 2020-06-14 11:47:51 | Sender: EibPC | GA: "Dach Ankleide-5/3/0" | Wert: AUS | Typ: Binärwert | Schreiben
      Das funktioniert auch. Rollo fährt runter, Rollo stoppt, Rollo fährt hoch.
      pshifter(RolloEssenID)[UP,BLIND,DOWN]$Rollo Essen/Küche$
      pshifter(RolloAnkleideID)[UP,BLIND,DOWN]$Rollo Ankleide$


      Nur die Anzeigen passt nicht.
      Beim Rollo für die Dachfläche ändert sich nicht die Anzeige, bei Essen/Küche klappt das super.

      Kommentar


        #4
        dann zeig doch mal noch deinen passenden Ausschnitt aus der Webserver Definition
        ....und versuchen Sie nicht erst anhand der Farbe der Stichflamme zu erkennen, was Sie falsch gemacht haben!

        Kommentar


          #5
          Klar kann ich machen.
          Ich habe die aber schon verglichen und keinen Unterschied erkennen können.

          1.) Seite mit Dach Rollos - Problem

          Code:
          // Seite für OG Steuerung und Studio
          Page(BeleuchtungOGSTPageID)[$OG und Studio$, $Steuerung OG+Studio$]
          header(0)
          footer(0)
          button(ClockWebID)[CLOCK]$Uhrzeit$ button(DateWebID)[DATE]$Datum$ button(LichtID)[LIGHT]$Alle Lichter$ button(RolloAutoID)[SWITCH]$Anwesenheit$ button(BeschattungID)[SWITCH]$Beschattung$
          line
          pbutton(BadDeckeID)[LIGHT]$Bad Decke$ pbutton(BadSpiegelID)[LIGHT]$Bad Spiegel$ none pshifter(RolloBadID)[UP,BLIND,DOWN]$Rollo Bad$
          line
          pbutton(SchlafenID)[LIGHT]$Schlafen$ pbutton(AnkleideID)[LIGHT]$Ankleide$ none pshifter(RolloAnkleideID)[UP,BLIND,DOWN]$Rollo Ankleide$
          line
          pbutton(ArbeitenID)[LIGHT]$Arbeiten$ button(AbendbeleuchtungID)[SWITCH]$Abendbeleuchtung$ none button(WakeupID)[SWITCH]$Wakeup NAS$ button(LichtOGID)[LIGHT]$Alle Lichter OG AUS$
          line
          pbutton(StudioDeckeID)[LIGHT]$Studio Decke$ pbutton(StudioBastelnID)[LIGHT]$Studio Basteln$ pbutton(StudioPCID)[LIGHT]$Studio PC$ pshifter(RolloStudioID)[UP,BLIND,DOWN]$Rollo Studio$
          line
          button(TerrassentuerID)[WINDOW]$Terrassentür$ button(HWRFensterID)[WINDOW]$HWR-Fenster$ button(DachfensterBadID)[WINDOW]$Badfenster$ button(DachfensterAnkleideID)[WINDOW]$Ankleidefenster$ button(KuechenfensterID)[WINDOW]$Küchenfenster$
          button(TerrassentuerBatID)[INFO]$Terrassentür$ button(HWRFensterBatID)[INFO]$HWR-Fenster$ button(DachfensterBadBatID)[INFO]$Badfenster$ button(DachfensterAnkleideBatID)[INFO]$Ankleidefenster$ button(KuechenfensterBatID)[INFO]$Küchenfenster$

          2.) Seite mit normalen Rolls - seit Jahren ohne Probleme

          Code:
          // Seite für Zentralsteuerung
          Page(ZentralPageID)[$Zentral und Rollo$, $Steuerung Zentral+Rollo$]
          header(0)
          footer(0)
          button(ClockWebID)[CLOCK]$Uhrzeit$ button(DateWebID)[DATE]$Datum$ button(LichtID)[LIGHT]$Alle Lichter$ button(RolloAutoID)[SWITCH]$Anwesenheit$ button(BeschattungID)[SWITCH]$Beschattung$
          line
          pshifter(RolloAlleID)[UP,BLIND,DOWN]$Rollo Alle$ none pshifter(RolloTerrasseID)[UP,BLIND,DOWN]$Rollo Terrasse$
          line
          pshifter(RolloEssenID)[UP,BLIND,DOWN]$Rollo Essen/Küche$ none pshifter(RolloOstID)[UP,BLIND,DOWN]$Rollo Straßenseite$
          line
          pshifter(RolloSuedID)[UP,BLIND,DOWN]$Rollo Wohnzimmer$
          line
          pshifter(RolloSchlafenID)[UP,BLIND,DOWN]$Rollo Schlafzimmer$ none none button(WakeupID)[SWITCH]$Wakeup NAS$
          line
          button(TerrassentuerID)[WINDOW]$Terrassentür$ button(HWRFensterID)[WINDOW]$HWR-Fenster$ button(DachfensterBadID)[WINDOW]$Badfenster$ button(DachfensterAnkleideID)[WINDOW]$Ankleidefenster$ button(KuechenfensterID)[WINDOW]$Küchenfenster$
          button(TerrassentuerBatID)[INFO]$Terrassentür$ button(HWRFensterBatID)[INFO]$HWR-Fenster$ button(DachfensterBadBatID)[INFO]$Badfenster$ button(DachfensterAnkleideBatID)[INFO]$Ankleidefenster$ button(KuechenfensterBatID)[INFO]$Küchenfenster$

          Kommentar


            #6
            Hi,

            der pshifter RolloAnkleideID (14) befindet sich auf der Seite BeleuchtungOGSTPageID (2).

            Du verwendest aber
            if event("Dach Ankleide-5/3/0") then { pdisplay(14,$Rollo fährt$,STOP,DARKRED,GREY,4) } endif

            Das ist die falsche Seiten-ID -> 2 statt 4.

            Kommentar


              #7
              Da kann man noch so viel schauen und prüfen...
              4 Augen sehen mehr als 2...
              :-)
              Vielen Dank, das war es !

              Kommentar


                #8
                Eher 6 mehr als 4.
                war ja meine Erste Vermutung, aber ich hab dann auch nützt Bäume statt Wald gesehen....
                ....und versuchen Sie nicht erst anhand der Farbe der Stichflamme zu erkennen, was Sie falsch gemacht haben!

                Kommentar


                  #9
                  Oh ja, da hast du natürlich Recht.
                  Dir auch vielen Dank, Uwe, für deine Unterstützung.
                  :-)

                  Kommentar

                  Lädt...
                  X