pslider für Temperatursollwert inkl. Ist-Wertanzeige

[Berra]

Hallo,

ich bin im Augenblick am erstellten meiner Visu, dank eurer Beiträge habe ich bis jetzt immer eine Lösungen für meine Probleme gefunden.
Jedoch für das aktuelle Problem habe ich leider keinen Ansatz im Forum gefunden.
Aber vermutlich sehe ich vor lauter Bäume den Wald nicht....

Meine Problem:
Ich möchte mit einem Schieberegler (pslider) den Temperatursollwert für die Heizung visualisieren und einstellen.
d.H. Ich möchte die Solltemperatur von 19 C° bis 24 C° einstellen können und die aktuelle Soll-Temperatur anzeigen.
Folgende Gruppenadressen habe ich zur Kommunikation mit meiner Heizung:
- Raumtemperatur Soll --> f16 (Rückmeldung der Heizung)
- Raumtemperatur einstellen

--> f16 (Vorgabe der Solltemperatur)

Gibt es hierfür ein fertiges Makro? Wenn ja welches?

Gruß Jens

[Kahler]

Dass es dafür ein fertiges Makro gibt, glaube ich nicht.

Ich habe das mit +/- Tasten realisiert, mit dem Thermometer-Icon in der Mitte, kann ich die Heizfunktion ein/ausschalten, außerdem wechselt das Icon die Farbe, wenn der Heizkreis offen ist.

[Berra]

Danke für deinen Tipp, das entspricht genau meinem Wunsch.
Hatte gehoft, dass es ein fertiges Makro gibt...

Kannst du mir deinen Programm Code als Muster zukommen lassen?
Es wäre super, wenn du mir den Teil für den Webserver und das verwendete Makro geben könntest.

Gruß Jens

[Uwe!]

bei mir sieht's so aus:

[enertegus]

vgl. Ordner Beispiele/WebV3/SliderTemperatur.epc in Makrolibs

[Berra]

Hallo zusammen,

Danke für eure Tipps.

@enertegus,
habe deinen Tipp getestet, leider zeigt mir die Anzeige keinen Ist-Wert an...
Zusätzlich ist der Slider am iPad nicht optimal zu bedienen, da die Temperatur nur auf den Bus übergeben wird, wenn auf das TEMPERATURE Symbol gedrückt wird. Dabei steigt jedoch die Temperatur um x Grad an....

@ Uwe,
dein Beispiel gefällt mir sehr gut. Kann ich hier mit den Tasten +/- die Solltemperatur einstellen?
Wenn ja wird diese sofort auf den Bus geschrieben?

@Kahler,

Kannst du mir deinen Programm Code als Muster zukommen lassen?

Gruß Jens

[Uwe!]

Kann ich hier mit den Tasten +/- die Solltemperatur einstellen?
Wenn ja wird diese sofort auf den Bus geschrieben?

Ja und ja.

[Berra]

Kannst du mir das Makro bzw. den Programmauszug zu senden?

[Uwe!]

Ja, ist momentan noch kein Makro, soll es aber mal werden.

[klaus_kraemer]

Bei mir ist's schon ein Makro (aus einer Reihe von Makros, die die gesamte Fernwärmeheizung steuern, deshalb tauchen hier vielleicht nicht auf den ersten Blick verständliche Variable auf):

//---------------- Pshifter auswerten
[B]:begin HeizenRadPshifter(Name, pID, pPgID, pGAsollTemp, pMaxTemp, pMinTemp, pIncrement)[/B]

//pGAsollTemp derzeit nicht verwendet, dienst später zur Kommunikation mit EibPC01

Name_OutText = $$
Name_SollText = $$
Name_IstText = $$
Name_VentilText = $$
Name_IconState = INACTIVE
Name_SollTempFlash = 22f16


if change(Name_Hauptschalter) then {
    if Name_Hauptschalter then {
        Name_IconState = STATE6;
    } else {
        Name_IconState = INACTIVE;
    } endif;
} endif;

[B]//........ Reaktion auf Tastenklicks[/B]
if pbutton(pID, pPgID) == 1 then {
    Name_SollTemp = max(Name_SollTemp - pIncrement, pMinTemp);
} endif;
if pbutton(pID, pPgID) == 2 then {
    Name_Hauptschalter = !Name_Hauptschalter;
} endif;
if pbutton(pID, pPgID) == 3 then {
    Name_SollTemp = min(Name_SollTemp + pIncrement, pMaxTemp);
} endif;

[B]//........ Ausgabe der Kontrollwerte[/B]
if change(Name_Ventilstatus) or systemstart() then {
    Name_VentilText = $Ventil: $ + convert(Name_Ventilstatus, $$) + $%$;
} endif;
if change(Name_IstTemp) or systemstart() then {
    Name_IstText = $Ist: $ + stringformat(Name_IstTemp,4,0,3,1) + $°C$;
} endif;
if change(Name_SollTemp) then {
    Name_SollText = $Soll: $ + stringformat(Name_SollTemp,4,0,3,1) + $°C$;
} endif;
if change(Name_SollText) or change(Name_IconState) or change(Name_IstText) or change(Name_VentilText) then {
    Name_OutText = Name_SollText + $&nbsp&nbsp$ + Name_IstText + $<br>$ + Name_VentilText;
    pdisplay(pID, Name_OutText, WALLHEATING, Name_IconState, GREEN, pPgID);
} endif;

[B]//........ Sollwertänderung nach 1 Minute speichern[/B]
if after(change(Name_SollTemp), 60000u64) then {
    if Name_SollTemp != Name_SollTempFlash then {
        Name_SollTempFlash = Name_SollTemp;
        writeflashvar(Name_SollTempFlash);
    } endif;
} endif
[B]//........ Sollwert nach Systemstart aus Flash holen[/B]
if systemstart() then {
    readflashvar(Name_SollTempFlash);
    Name_SollTemp = Name_SollTempFlash;
} endif

:end

und sieht dann so aus:

Rdiatoren.PNG

[Uwe!]

Kannst du mir das Makro bzw. den Programmauszug zu senden?

besser spät als nie...

der EibPC Teil ist das hier:

if change("Soll EG Flur-11/4/20") or change(Diff_EG_Flur) or change("Ist EG Flur-11/0/20") or change("H - Flur EG/ Garderobe-6/2/10") then pdisplay(20, $<font color=lime>$ + round("Soll EG Flur-11/4/20", 1, AUS) + $°C <font color=blue>$ + round("Ist EG Flur-11/0/20", 1, AUS) +$°C <font color=yellow>$ + round(Diff_EG_Flur, 1, AUS) + $°K <font color=red>$ + round(convert("H - Flur EG/ Garderobe-6/2/10", 0.0f16) / 2.55, 0, AUS) + $%$, MINUS, INACTIVE, GREEN, 93) endif

if pbutton(20, 93) == 1 then write("Vorgabe EG Flur-6/7/20", ("Soll EG Flur-11/4/20"/10.0f16 + 0.01f16) * 10.0f16) ; read("Soll EG Flur-11/4/20") endif
if pbutton(20, 93) == 2 then write("Vorgabe EG Flur-6/7/20", ("Soll EG Flur-11/4/20"/10.0f16-0.01f16) * 10.0f16) ; read("Soll EG Flur-11/4/20") endif

if pbutton(21, 93) == 1 then write("Betriebsmodus EG Flur-11/1/20", KOMFORT) endif
if pbutton(21, 93) == 2 then write("Betriebsmodus EG Flur-11/1/20", STANDBY) endif
if pbutton(21, 93) == 3 then write("Betriebsmodus EG Flur-11/1/20", NACHTMODUS) endif
if pbutton(21, 93) == 4 then write("Betriebsmodus EG Flur-11/1/20", 4) endif

if "Betriebsmodus EG Flur-11/1/20" == KOMFORT then BM_EG_Flur = $Anwesend$ endif
if "Betriebsmodus EG Flur-11/1/20" == STANDBY then BM_EG_Flur = $Abwesend$ endif
if "Betriebsmodus EG Flur-11/1/20" == NACHTMODUS then BM_EG_Flur = $Nacht$ endif
if "Betriebsmodus EG Flur-11/1/20" == 4 then BM_EG_Flur = $Frost$ endif

if change("Betriebsmodus EG Flur-11/1/20") then pdisplay(21, BM_EG_Flur, ICE, INACTIVE, GREEN, 93) endif

und der Webserver Teil:

page(93)[$Statusmeldungen$, $Heizungsaktoren EG$]
header(0)
footer(0)
design $black$
compact(on)
pshifter(20)[PLUS, MINUS]$EG Flur: Soll / Ist / &Delta; / %$ mpchart(31)[SINGLE, 8] ($8Stellgröße$, LINE, $Temp.Diff$, COLUMN)
pshifter(21)[PRESENT, ABSENT, NIGHT, ICE]$Betriebsmodus$

[Berra]

Super vielen Dank.