Hier mal aus dem Betaforum zum Testen und modifizieren...
Code:
[WebServer]
page(SumID)[$Allgemein$,$Wetter$]
button(TimeID)[CLOCK]$Uhrzeit$ button(DateID)[DATE]$Datum$ pshifter(SunID)[INFO]$Sonnenauf- und Untergang$
line $Wetterstation am Wintergarten$
button(LuxID)[WEATHER] $Licht in Lux $ button(WindID)[WIND]$Wind in m/s$ pshifter(TempID)[TEMPERATURE]$Außentemp.: Min und Max in °C$
picture(0)[DOUBLE,CENTERGRAF]($Vorhersage$,$http://de.weather.yahoo.com/images/eur_germany_outlook_DE_DE_440_dmy_y.jpg$)\\
picture(1)[DOUBLE,CENTERGRAF]($Satellitenbild$,$http://de.weather.yahoo.com/images/eur_satintl_440_dmy_y.jpg$)
[EibPC]
// Seiten
SumID=1
//Buttons auf S. 1
TimeID=0
DateID=1
SunID=2
LuxID=3
WindID=4
TempID=5
// WetterDaten
Wind = "Wind-3/5/1"
Licht ="Licht-3/5/2"
AussenTemperatur="ThermeAußentemperatur-3/3/13"
Regen="RegenMeldung-5/2/2"
RegenText=$$
if Regen then RegenText=$ - Es regnet$ else RegenText=$ - Es regnet nicht$ endif
Sonnenaufgang=stringformat(sunrisehour(),0,3,2,2)+$:$+stringformat(sunriseminute(),0,3,2,2)
Sonnenuntergang=stringformat(sunsethour(),0,3,2,2)+$:$+stringformat(sunsetminute(),0,3,2,2)
// Maximale und Minimale Temperatur eines Tages berechnen
MaxTemp=-99.0
MinTemp=99.0
if htime(00,00,00) then {
MaxTemp=AussenTemperatur;
MinTemp=AussenTemperatur
} endif
if MaxTemp<AussenTemperatur then MaxTemp=AussenTemperatur endif
if MinTemp>AussenTemperatur then MinTemp=AussenTemperatur endif
// Webserver Seite 1
Init=after(systemstart(),5000u64)
if stime(0) then webdisplay(TimeID,settime(),CLOCK,DISPLAY,GREEN) endif
if change(setdate()) or Init then webdisplay(DateID,setdate(),DATE,DISPLAY,GREEN) endif
if change(Wind) then webdisplay(WindID,Wind,WIND,DISPLAY,GREY) endif
if change(Licht) then webdisplay(LuxID,Licht,WEATHER,DISPLAY,GREY) endif
if change(Sonnenaufgang) or Init or change(RegenText) then pdisplay(SunID,Sonnenaufgang+$ - $+Sonnenuntergang +RegenText,INFO,DISPLAY,GREY,SumID) endif
if change(MinTemp) or change(MaxTemp) then {
pdisplay(TempID,convert(MinTemp,$$) +$ : $+ convert(MaxTemp,$$),TEMPERATURE,DISPLAY,GREY,SumID)
}endif
Kommentar