automatische Beschattung

[JoergA]

Hallo zusammen,

ich versuche nun endlich mal eine automatisierte Beschattung, basierend auf der zu erwartenden Temperatur und der Werte Azimut/Elevation.
Nachdem ich nun endlich die Wetterdaten über DarkSky abfragen kann (musste das 1.9.0er Wetterbinding in meine 1.7.x OH Installation kopieren), versuche ich mich nun an den richtigen Werten für Azimut und Elevation für die Parameter der Steuerung.

Wenn meine Ost-Seite wirklich 100% Ost - also 90 Grad Azimut - wäre, ab wann würdet ihr dann beschatten? +/- 60 Grad oder ist das zu konservativ?

Sprich:
Osten => bei 30 Grad Rollladen ab und bei 150 Grad wieder auf
Süden => bei 120 Grad ab und bei 240 Grad wieder auf
Westen => bei 210 Grad ab und bei 330 Grad wieder auf

Habe schon einige Zeit vor dem Haus verbracht, aber nicht die Werte gefunden wann eine Hausseite besonnt wird :-(

Der Azimut ist doch - gegenüber der Elevation - über das Jahr "stabil", korrekt??

Viele Grüße,
Jörg

[starwarsfan]

Hallo Jörg,

beschattet wird i.d.R. ab dem Zeitpunkt, wenn die Sonne auf der jeweiligen Fassade durch das Fenster scheint bzw. bis zu dem Zeitpunkt, wo sie es nicht mehr tut. Somit gibt es zwei Offsets zum Azimut der Fassade. Schau Dir doch mal die Eingänge des Edomi-Beschattungsbausteines an. Dann bekommst Du eine Idee, in welche Richtung sich soetwas entwickelt...

[sihui]

oder gib deine Koordinaten hier ein und ermittel die Werte grafisch:

http://www.sonnenverlauf.de/

[JoergA]

Hallo Jörg,

beschattet wird i.d.R. ab dem Zeitpunkt, wenn die Sonne auf der jeweiligen Fassade durch das Fenster scheint bzw. bis zu dem Zeitpunkt, wo sie es nicht mehr tut. Somit gibt es zwei Offsets zum Azimut der Fassade. Schau Dir doch mal die Eingänge des Edomi-Beschattungsbausteines an. Dann bekommst Du eine Idee, in welche Richtung sich soetwas entwickelt...

Danke, die Antwort wäre dann also - bei diesem Baustein - +/- 90Grad Also 50% mehr als ich geplant habe.
Das Ganze läuft bei mir dann über die zu erwartende Außentemperatur und Azimut/Elevation, da ich zwar einen Lichtfühler habe, aber auch ein ständiges auf und ab der Rollladen vermeiden möchte.

Gruß,
Jörg

[starwarsfan]

Hallo Jörg

Danke, die Antwort wäre dann also - bei diesem Baustein - +/- 90Grad Also 50% mehr als ich geplant habe.

Ähm, nein. +/- 90° sind die Default-Werte, welche maximal möglich sind. I.d.R. wird da aber jeweils entsprechend weniger konfiguriert, da das von den örtlichen Gegebenheiten wie bspw. benachbarte Gebäude, Dachüberstand etc. pp. abhängt.

Das Ganze läuft bei mir dann über die zu erwartende Außentemperatur und Azimut/Elevation, da ich zwar einen Lichtfühler habe, aber auch ein ständiges auf und ab der Rollladen vermeiden möchte.

Das unnötige Verfahren zu vermeiden ist die grosse Kunst bei dem ganzen Spielchen...

[JoergA]

Danke für die Tipps, haben mir sehr weiter geholfen

[imhofa]

Und wie hast Du das jetzt konkret gelöst?
Andreas

[ArPa]

Und wie hast Du das jetzt konkret gelöst?

Guter Punkt Stehe auch gerade davor, eine openHAB Rule zu schreiben. http://www.sonnenverlauf.de veranschaulicht auf jeden Fall sehr gut mit Hilfe der Animationsfunktion wie sich Azimut und Elevation im Tagesverlauf entwickeln. Die Erstellung einer openHAB Rule wäre auf jeden Fall für viele nützlich. Vielleicht kann man von der Erfahrungen im Edomi Baustein profitieren.

Beste Grüße,
ArPa

[sihui]

Die Erstellung einer openHAB Rule wäre auf jeden Fall für viele nützlich.

Als ich vor einem Jahr meine Rollläden auf elektrischen Antrieb umgerüstet habe stand ich vor dem gleichen Problem und konnte keine Beispiel-Rules finden. Inzwischen weiß ich warum: solche Rules sind extrem individuell und deshalb macht es auch keinen Sinn fertige Beispiele zu nehmen um zu versuchen diese auf seine eigenen Gegebenheiten anzupassen.
Angefangen habe ich mit verschachtelten If-Anweisungen, was direkt zum Scheitern verurteilt war. Einige Tipps im englischen Forum haben mir dann auf die Sprünge geholfen. Da ich nur eingeschränkte Skript-Kenntnisse habe, hat folgende Vorgehensweise zum Erfolg geführt:

Immer nur einzelne Sensoren bzw. Logiken zu jeweils einem virtuellen Item (ohne Binding-Anbindung) zusammenfassen und dann daraus die endgültige Gesamtlogik bilden. Das sieht bei mir dann wie folgt aus. Es sind allerdings nur Teile der Gesamt-Rule, insgesamt müssen ja mehr als ein Rollo eingebunden werden (bei mir sind es sechs an drei verschiedenen Hausseiten).
Jemand der besser mit Groups und Logiken umgehen kann ist mit Sicherheit in der Lage, das kürzer und eleganter zu machen, doch meine Vorgehensweise funktioniert und ist wenigstens für Nicht-Programmierer nachvollziehbar:

Zuerst einige values am Anfang der rule setzen um später nicht in der langen rule nach den Werten suchen zu müssen falls sie geändert werden müssen:

val Number SunDetectLux = 35000 //in lux
val int LuxHysteresis = 5 //in minutes

val Number ShadingKitchenEastPosition = 65  //in procent
val Number ClosedKitchenEastPosition = 85

val Number SunAzEastStart = 60
val Number SunAzEastEnd = 150
val Number SunElEastStart = 6
val Number SunElEastEnd = 50

Dann eine rule die ein virtuelles Item auf ON schaltet wenn die Sonne scheint. Hier wird auch eine Hysterese eingebaut, damit nicht bei jedem Sonnenstrahl die Rollos gleich zugehen:

rule "sun lux roof detection"
when
    Item ESP8266_Four_Lux received update
then
    var Number Lux_four_avg = ESP8266_Four_Lux.averageSince(now.minusMinutes(LuxHysteresis))
    ESP8266_Four_Lux_AVG.postUpdate(Lux_four_avg)
    if (Lux_four_avg > SunDetectLuxTop) {
        ShutterLuxTopDetected_Proxy.sendCommand(ON)
    }
    else {
        ShutterLuxTopDetected_Proxy.sendCommand(OFF)
    }
end

Dann eine rule die ggf. mehrere Luxsensoren auf ein virtuelles Item vereint.

Dann eine rule, die die Az und El Werte vom Astro binding verarbeitet und für die jeweilige Hausseite ein virtuelles Item auf ON schaltet wenn die Bedingungen erfüllt sind. Die El kann man sich eigentlich sparen, ich habe nur noch keine Zeit gehabt das wieder rauszunehmen:

rule "sun position east"
when
    Item Sun_Az received update or
    Item Sun_El received update
then
    if ((Sun_Az.state > SunAzEastStart && Sun_Az.state < SunAzEastEnd) && (Sun_El.state > SunElEastStart && Sun_El.state < SunElEastEnd)) {
        Shading_Shutter_SunPositionEast_Proxy.sendCommand(ON)
    }
    else {
        Shading_Shutter_SunPositionEast_Proxy.sendCommand(OFF)
     }
end

Dann eine rule, die alles zu einem virtuellen Item zur Freischaltung des Rollladens vereint, gleichzeitig über das Expire Binding einen Schalter schaltet, der das Rollo für xx Minuten nicht wieder öffnet (falls die Sonne weg ist und sich nicht ständig das Rollo bewegen soll) und zusätzlich noch einen Schalter beinhaltet, der die gesamte Sonnenautomatik ein- und ausschalten kann:

rule "combine everything to one autoshade proxy switch for kitchen east"
when
    Item Shading_Shutter_Enable_Proxy received update or
    Item SunDetected_Proxy received update or
    Item Shading_Shutter_SunPositionEast_Proxy received update

then
    if (Shading_Shutter_Enable_Proxy.state==ON && Shading_Shutter_SunPositionEast_Proxy.state==ON && SunDetected_Proxy.state==ON) {
    Shading_Shutter_East_Autoshade.sendCommand(ON)
    ShutterDelayTimerKitchen_East.sendCommand(ON) //über Expire Binding nach xx Minuten auf OFF schalten
    }
    else {
    Shading_Shutter_East_Autoshade.sendCommand(OFF)
    }
end

Dann kommt die rule, die letztendlich das Rollo öffnet und schließt:

rule "move shutters east to shading position = main execution"
    when
        Item Shading_Shutter_East_Autoshade received update
    then
        if (Shading_Shutter_East_Autoshade.state==ON && ShutterOverrideTimerKitchen_East.state==OFF && ShutterAutoOpenCloseKitchen_Lock.state==OFF) {
            if (FibFGR222_Kitchen_East.state != ShadingKitchenEastPosition) {
            FibFGR222_Kitchen_East.sendCommand(ShadingKitchenEastPosition)
            }
        }
        else if (Shading_Shutter_East_Autoshade.state==OFF && ShutterOverrideTimerKitchen_East.state==OFF && ShutterAutoOpenCloseKitchen_Lock.state==OFF && ShutterDelayTimerKitchen_East.state==OFF) {
              if (FibFGR222_Kitchen_East.state > 3) {
                  FibFGR222_Kitchen_East.sendCommand(0)
             }
        }
end

Dann zwei rules, die über das Astro binding abends die Rollos schließen und morgens wieder öffnen und gleichzeitig noch einen Lock setzt, der verhindert das in der Zeit dazwischen sich irgend ein Rollo bewegen kann., Gleichzeitig wird ein virtueller Switch eingesetzt, der diese Funktion für alle Rollos ein- und ausschaltet:

rule "shutter kitchen auto close east"
when
    Channel 'astro:sun:shutterkitchen:set#event' triggered END
then
    if (AutoOpenClose_Shutter_Proxy.state==ON) {
        FibFGR222_Kitchen_East.sendCommand(ClosedKitchenEastPosition)
        ShutterAutoOpenCloseKitchen_Lock.sendCommand(ON)
    }
    else if (AutoOpenClose_Shutter_Proxy.state==OFF) {
        ShutterAutoOpenCloseKitchen_Lock.sendCommand(OFF)
     }
end

rule "shutter kitchen auto open east"
when
    Channel 'astro:sun:shutterkitchen:civilDawn#event' triggered START
then
    if (Shading_Shutter_East_Autoshade.state==OFF && (ShutterOverrideTimerKitchen_East.state==OFF || ShutterOverrideTimerKitchen_East.state==NULL) && AutoOpenClose_Shutter_Proxy.state==ON && ShutterAutoOpenCloseKitchen_Lock.state==ON) {
        FibFGR222_Kitchen_East.sendCommand(0)
        ShutterAutoOpenCloseKitchen_Lock.sendCommand(OFF)
        //logInfo("SHUTTER", "shutters kitchen east auto opened")
    }
    else if (Shading_Shutter_East_Autoshade.state==ON && ShutterOverrideTimerKitchen_East.state==OFF && AutoOpenClose_Shutter_Proxy.state==ON) {
        FibFGR222_Kitchen_East.sendCommand(ShadingKitchenEastPosition)
        ShutterAutoOpenCloseKitchen_Lock.sendCommand(OFF)
        ShutterDelayTimerKitchen_East.sendCommand(ON)
        //logInfo("SHUTTER", "shutters kitchen east not auto opened because autoshade is ON")
    }
    else if (ShutterOverrideTimerKitchen_East.state==ON || AutoOpenClose_Shutter_Proxy.state==OFF) {
        ShutterAutoOpenCloseKitchen_Lock.sendCommand(OFF)
        //logInfo("SHUTTER", "shutters kitchen east not auto opened because override flag is set or function disabled")
        }
end

Die gesamte Rule ist etwa drei bis viermal so lang, da bei mir noch einige Szenenschaltungen dazu kommen und natürlich die restlichen zwei Hausseiten abgebildet werden müssen.

[ArPa]

sihui Jep, das habe ich gestern Abend auch gemerkt. Alleine die Werte für die jeweiligen Fassaden/Fenster variieren ja sogar teilweise von Fenster zu Fenster! Wie habt ihr/hast Du das gemacht? Zu Anfang Erfahrungswerte gesammelt und geschaut bei welchem Azimut und Elevation noch Sonneneinstrahlung im jeweiligen Zimmer ist oder lässt sich das "berechnen"?

Habe gestern Abend überlegt es mir zunächst in den Sommermonaten einfach zu machen und eine Fassade nach Sonnenaufgang zu beschatten und nach Sonnenhöchststand einfach die Beschattung an den Fassaden zu wechseln. Eine gewisse Zeit steht die Sonne ja direkt über unserem Haus. Bis auf die Dachflächenfenster ist dann nirgendwo Sonneneinstrahlung. Bis dann in den Mittags-/Nachmittagsstunden wieder eine Fassade angestrahlt wird.

Ist für den Anfang vielleicht nicht perfekt aber zweckmäßig.

[sihui]

sihui Wie habt ihr/hast Du das gemacht?

Nein, sondern wie oben schon erwähnt: https://knx-user-forum.de/forum/supp...83#post1086683

[ArPa]

Naja, das hilft ja nur näherungsweise. Je nach Fenster ist z.B. aufgrund des Dachüberstandes das eine früher im Schatten, das andere später. Obwohl man dort auf der Seite etwas mit der Objekthöhe spielen kann, läuft es meiner Meinung nach auf "Erprobung" aus, wenn man es wirklich genau haben will. Nur dann lohnt sich die Mühe meiner Meinung nach auch, denn für eine einfache Fassadensteuerung benötigt es gar nicht so genaue Azimut und Elevation Werte wie mir scheint.

[sihui]

denn für eine einfache Fassadensteuerung benötigt es gar nicht so genaue Azimut und Elevation Werte wie mir scheint.

Nein, grob reicht. Solange mir die pralle Sonne nicht ins Fenster scheint bin ich zufrieden ...

[udo1toni]

Kommt halt darauf an, wieviel Mühe man in ein Detail reinstecken möchte. Ich habe zum Beispiel eine total popelige Lösung genommen. Meine Läden fahren zeitgesteuert auf, verschiedene Gruppen zu verschiedenen Zeiten, aber im großen und Ganzen reduziert es sich auf "Sonnenaufgang" für die Teile des Hauses, in denen niemand schläft und feste Uhrzeiten für Kinder/Eltern-Zimmer (manuell(* abhängig vom Stundenplan, wobei an Wochenenden, beweglichen Feiertagen und Ferien zu frühes Öffnen vermieden wird). Dabei werden die Bereiche, die schon geöffnet wurden, jeweils nochmals mit geöffnet (hat dann keine Auswirkungen).
Geschlossen werden die Läden nach Sonnenuntergang und in den Schlafbereichen spätestens um 20 Uhr.

Wenn die Temperaturvorhersage für den aktuellen Tag mehr als 23 °C beträgt, werden die zu verschattenden Bereiche einfach um 9 Uhr auf Verschattungsposition gefahren.
Allerdings hat mein Haus Fensterläden nur nach Norden, Süden und Westen, wobei im Westen nur ein Fenster theoretisch direkt Sonnenstrahlen abbekommen könnte, der Süden ist dann eh komplett beschienen und die Lichtverhältnisse sind mit Verschattung den ganzen Tag über sehr angenehm. Die Dachfenster müssen ohnehin geschlossen bleiben, um nicht den Hitzetod zu sterben (seit die PV-Anlage das Dach beschattet, ist das wesentlich besser geworden, aber wir haben immer noch wochenlang Stauwärme, wenn es auch nur einen Tag richtig drauf geknallt hat - wohlgemerkt im Frühling...)

(* manuell insofern, dass ich halbjährlich die entsprechenden Zeiten händisch eintrage, weil die Stundenpläne bisher nicht digital vorliegen...

[imhofa]

Hier ein ganz tolles Lob an sihui und udo1toni !
Genau diese Beschreibungen bzw. "fertige" Lösungen helfen ungemein eine Vorstellung zu bekommen, was man alles in so eine Automatik verwursteln kann.
Solche Dinge helfen mir selbst zumindest, Lösungen zu finden, die für mich passen.

Wir rüsten gerade die Rollläden von Gurt auf Rohrmotor um und in diesem Zuge wird Zimmer für Zimmer per LCN auf den Bus gebracht und somit für openHab zugänglich. Bei uns gibt es im Moment zwei "Schaltungen": zeitbasiert (morgens hoch, abends runter) und komplett manuell (Schalter).

Gerade jetzt im Sommer ist der große Vorteil, dass ja auch tagsüber, wenn niemand zu Hause ist, die Abschattung funktionieren könnte, wenn ich denn schon die Regeln dafür mir überlegt hätte. Viele Infos stehen ja zur Verfügung: Sonnenstand aus dem Astro-Binding, Wettervorhersage aus dem Weather-Binding, tatsächliche Außentemperatur über den eingebundenen Heizkessel,...

Viel schlimmer ist ja: wie soll wann was passieren?
Vieles habt Ihr schon angesprochen: Feiertage, Wochenenden, Ferienzeiten, Stundenpläne, Sonnenstand, Bewölkung, Zustand Balkon-/Terrassentüre, MANUELLER EINGRIFF, ...

Ich sehe schon, da wird wieder einige Zeit draufgehen, sich das ganze grundsätzlich zu überlegen und dann auch zu realisieren (und debuggen).

Vielen Dank nochmals, dass Ich Eure Lösungen hier niedergeschrieben habt.

Andreas