ARDUINO am KNX

[WagoKlemme]

Ja, das sind schnöde Offsets.
Das Thema ist für mich insofern interessant, da ich meine 12 Elsner Temp-/Feuchteregler erstaunlicher Weise exakt (!) um 3% nach oben korrigiert. Heisst im Umkehrschluss die Elsner und der BME280 messen gleich.
Dann wäre nur mein Testo falsch.

Andererseits ist die Temperatur des BME um 2K (genau 2,2K) daneben. Deshalb dachte ich, wenn die Temperatur schon so falsch ist, dann ist die Feuchte auch sicher daneben. Die Temperatur habe ich mit einem Präzisionsthermometer, das ich von der Firma hatte, gemessen. Das stimmt sicher, da unsere Kunden das gefühlt schon 1000mal nachgemessen und nie beanstandet haben.

Den Luftdruck habe ich von weatherunderground und mit unserer Wetterstation annähernd abgeglichen. Seitdem arbeiten aber alle 3 exakt parallel.

Die 3% bei der Feuchte entscheiden aber häufig über mehr Lüften, deshalb wäre es schon wichtig richtig zu messen.

[wintermute]

Die 3% bei der Feuchte entscheiden aber häufig über mehr Lüften, deshalb wäre es schon wichtig richtig zu messen.

WU als Referenz ist - denke ich - eher suboptimal, wer weiss schon was die da fuer Sensoren haben?
Bei den 3% waere es IMHO am sinnvollsten zwei "gleichmessende" Sensoren zu vergleichen, einen innen und einen aussen. Der Absolutwert ist da ja eher weniger interessant, es geht doch mehr um die Differenz, oder?

[WagoKlemme]

Vielleicht gibts von dem BMEs auch Chargen die schlecht geloetet wurden oder so, weiss man nicht. Fuer mich waren die bisher jedenfalls Plug&Play, einfach anschliessen und loslegen.

Das könnte tatsächlich der Punkt sein. Für 9 Euro aus Deutschland (!) fast naheliegend.
Aber mit Offsets läuft er schön.

[WagoKlemme]

WU war nur für den Luftdruck !
Da ist weniger der absolut gemessene Wert, sondern eher die Veränderung interessant. Also in der Praxis vertretbar.
Mein Feuchte-Testo-Teil hat eine "angegebene" Genauigkeit von +-1,5%, was imho schon sehr gut ist. Vielleicht ist das Prüfprotokoll nur immer weiterkopiert ?

[WagoKlemme]

WU als Referenz ist - denke ich - eher suboptimal, wer weiss schon was die da fuer Sensoren haben?
Bei den 3% waere es IMHO am sinnvollsten zwei "gleichmessende" Sensoren zu vergleichen, einen innen und einen aussen. Der Absolutwert ist da ja eher weniger interessant, es geht doch mehr um die Differenz, oder?

Die Elsner messen alle fast auf den Punkt (nicht Kommastelle aber %) gleich. Die hatte ich vor zwei Jahren alle durchprobiert an der gleichen Messstelle.

Edit: Mann bist Du schnell !
Die Werks-Kalibrierung deiner BMEs scheint wirklich gut zu sein. Besser gehts nicht. Beeindruckend.

[snowdd]

Beim Luftdruck gibt es zwei Werte: Absolut und korrigiert auf Meereshöhe (N.N.)
Eigentlich alle Informationen die man aus Wetterprogrammen, Funk und Fernsehen etc. bekommen sind auf NN geeicht, ansonsten hat der Nachbar auf dem Hügel ja einen anderen Wert.
Insofern gehe ich davon aus dass das relativ große Offset eigentlich nur Deine Korrektur der Höhe Deines Wohnorts war, und das Teil ansonsten sehr gut kalibriert und stabil ist (keine Verzerrung, kein Abwandern)

Das klingt so gut, dass das Teil mit auf meine Bastelideenliste kommt!

gruß
raoul

[wintermute]

Die Werks-Kalibrierung deiner BMEs scheint wirklich gut zu sein. Besser gehts nicht. Beeindruckend.

Ich hoffe, das wird bei den Zukuenftigen ebenfalls so sein

Was mir noch fehlt ist irgendein kleines weisses Gehaeuse so etwa in der Art vom AM2302, vllt optisch etwas ansprechender...
Die Dinger in der Zwischendecke zu verbauen funktioniert naemlich ueberhaupt garnicht - zumindest nicht wenn man Ansprechzeiten von unter 2 Tagen bevorzugt

[WagoKlemme]

Nein, der Luftdruck muss korrigiert auf deine Meereshöhe zum Zeitpunkt des Programmstarts im Code (in meinem Fall 1018hPa) eingegeben werden. Auch nach Berücksichtigung der Meereshöhe hat er dann 968hPa angezeigt. Und somit lag er exakt 50 daneben.

Ich denke Michael hat einen Sensor erwischt aus der Anfangsphase (sauber verarbeitet), bevor die Kopien kamen. Meine Chinakopie kann durchaus erhebliche Abweichungen haben, abhängig von der Kopierqualität. Denn eine Abweichung bei der Temperatur von 2,2K ist schon erheblich. Offensichtlich hat das der Sensor von Michael nicht.

[WagoKlemme]

Die Dinger in der Zwischendecke zu verbauen funktioniert naemlich ueberhaupt garnicht - zumindest nicht wenn man Ansprechzeiten von unter 2 Tagen bevorzugt

Was willst Du denn bitte in der Zwischendecke messen ? Oder kommst Du an eine andere Stelle nicht mehr mitm Kabel hin ?

Zur Feuchte:
Du weisst schon, was Du mit deinen Sensoren ausgelöst hast. Vormittag war für mich die Welt noch in Ordnung, jetzt muss ich zur Therapie.

[wintermute]

Was willst Du denn bitte in der Zwischendecke messen ?

In der Zwischendecke liegen die rPi-Squeezeplayer, die dann praktischerweise gleich das komplette Messprogramm des BME280 per HTTP an Edomi schicken koennen. Drum dacht ich, ich "leg" den BME einfach daneben, aber die Testtemperaturmessung war dann doch eher ernuechternd...
Also waer jetzt son kleines Gehaeuse nett, dass ich von unten an die Decke schrauben koennte. Berker-Sensoreinsatz ist mir dafuer etwas zu gross.

Du weisst schon, was Du mit deinen Sensoren ausgelöst hast. Vormittag war für mich die Welt noch in Ordnung, jetzt muss ich zur Therapie.

Ich kenn das, darum hab ich das Thema fuer mich selbst schon vor langer Zeit intern abgehakt

[WagoKlemme]

Mein CCS811 ist eingetroffen !
Bevor jemand viel Zeit wegen einer fehlerhaften LIB vergeudet, so wie ich, hier der Code :
PIN WAK auf 4 Pro Mini. VCC, GND, SDA, SCL ist klar. Hiermit wird der MODE 3 aktiviert. D.h. alle 10s gepulst eine Messung. Für 60s bitte in der LIB das Byte ändern, ist mit Pfeilen markiert.
Zur Genauigkeit zum iAQ kann ich im Moment sagen, das der CCS811 (nach Burn-in) bei CO2 400ppm mehr misst als der iAQ und VOC ca. 200 weniger. Beide lagen direkt nebeneinander.
Welcher nun stimmt weiss ich noch nicht.
Edit: CO2 stimmt inzwischen ziemlich überein. Nur VOC 2ppb (CCS811) zu 131ppm(iAQ) scheint dann doch daneben. Da scheint was faul zu sein.

Der CCS811 braucht ein 48h Burn-in. Danach 20min. Nach Modeänderung auch 20min.

Programm:

/***************************************************
  This is an example for the CCS811 digital TVOC/eCO2 Sensor by CCMOSS/AMS
  http://www.ccmoss.com/gas-sensors#CCS811
  Updated: March 28, 2017

  The sensor uses I2C protocol to communicate, and requires 2 pins - SDA and SCL
  Another GPIO is also required to assert the WAKE pin for communication. this
  pin is passed by an argument in the begin function.
  A breakout board is available: https://github.com/AKstudios/CCS811-Breakout
  The ADDR pin on the sensor can be connected to VCC to set the address as 0x5A.
  The ADDR pin on the sensor can be connected to GND to set the address as 0x5B.
  Written by Akram Ali from AKstudios (www.akstudios.com)
  GitHub: https://github.com/AKstudios/
 ****************************************************/

#include <CCS811.h>

#define ADDR      0x5A
#define WAKE_PIN  4

byte stat;
byte measure;

CCS811 sensor;

void setup()
{
  Serial.begin(9600);
  Serial.println("CCS811 test");
  if(!sensor.begin(uint8_t(ADDR), uint8_t(WAKE_PIN)))
  Serial.println("Initialization failed.");
  pinMode(WAKE_PIN, OUTPUT);
  digitalWrite(WAKE_PIN, LOW);
  stat=sensor.readStatus();
  measure=sensor.readMeasure();
  Serial.print("Status Byte : "); Serial.print(stat); Serial.println("");
}

void loop()
{
    stat=sensor.readStatus();
    if (bitRead(stat,3)) {


    sensor.compensate(21.9, 48.2);  // replace with t and rh values from sensor
    sensor.getData();
    Serial.print("CO2 : "); Serial.print(sensor.readCO2()); Serial.println(" ppm");
    Serial.print("TVOC : "); Serial.print(sensor.readTVOC()); Serial.println(" ppb");
    Serial.print("Measure Byte : "); Serial.print(measure); Serial.println("");
    if (!bitRead(stat,0)) {
       Serial.print("Status : "); Serial.println("ok");
    }
    if (bitRead(stat,0)) {
      Serial.print("Status : "); Serial.println("Error");
    }
    if (!bitRead(stat,3)) {
      Serial.print("Data : "); Serial.println("No data");
    }
    if (bitRead(stat,3)) {
      Serial.print("Data : "); Serial.println("ready");
    }
    Serial.println();
    bitWrite(stat,3,0);
    delay(1000);
  //}
  }
  delay(100);
}

LIB CCS811.cpp:

/***************************************************
  This is a library for the CCS811 digital TVOC/eCO2 Sensor by CCMOSS/AMS
  http://www.ccmoss.com/gas-sensors#CCS811

  Updated: April 18, 2017

  The sensor uses I2C protocol to communicate, and requires 2 pins - SDA and SCL
  Another GPIO is also required to assert the WAKE pin for communication. this
  pin is passed by an argument in the begin function.

  A breakout board is available: https://github.com/AKstudios/CCS811-Breakout

  The ADDR pin on the sensor can be connected to VCC to set the address as 0x5A.
  The ADDR pin on the sensor can be connected to GND to set the address as 0x5B.

  Written by Akram Ali from AKstudios (www.akstudios.com)
  GitHub: https://github.com/AKstudios/

  BSD license, all text above must be included in any redistribution
 ****************************************************/

#include "CCS811.h"

CCS811::CCS811()
{
  // empty constructor, just because.
}


boolean CCS811::begin(uint8_t I2C_ADDR, uint8_t WAKE_PIN)
{
  delay(70); // from datasheet - up to 70ms on the first Reset after new application download; up to 20ms delay after power on
  _I2C_ADDR = I2C_ADDR;
  _WAKE_PIN = WAKE_PIN;
  Wire.begin();
  pinMode(_WAKE_PIN, OUTPUT);   // set WAKE pin as OUTPUT
  PORTD &= ~(1<<PORTD4);  // assert WAKE pin LOW to initiate communication with sensor
  digitalWrite(_WAKE_PIN, LOW);  // WAKE_PIN on the sensor is active low, must always be asserted before any communication and held low throughout

  byte hw_id = CCS811::readHW_ID();
  if(hw_id != 0x81)  // this is the expected hardware ID
  {
    Serial.println("Error: Incorrect Hardware ID detected.");
    return false;
  }

  byte status = CCS811::readStatus();
  uint8_t bit = (status & (1 << 5-1)) != 0; // black magic to read APP_VALID bit from STATUS register
  if(bit != 1)
  {
    Serial.println("Error: No application firmware loaded.");
    readErrorID(status);
    return false;
  }

  digitalWrite(_WAKE_PIN, LOW);
  Wire.beginTransmission(_I2C_ADDR); // least significant bit indicates write (0) or read (1)
  Wire.write(APP_START);
  Wire.endTransmission();
  digitalWrite(_WAKE_PIN, HIGH);

  status = CCS811::readStatus();
  bit = (status & (1<<8-1)) !=0; // black magic to read FW_MODE bit from STATUS register
  if(bit != 1)
  {
    Serial.println("Error: Firmware still in boot mode.");
    readErrorID(status);
    return false;
  }

  digitalWrite(_WAKE_PIN, LOW);
  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(MEAS_MODE);
  Wire.write(B101000);  // constant power mode, IAQ measurement every 10 second  - B111000 = every 60s  <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
  Wire.endTransmission();
  //CCS811::sleep();
  digitalWrite(_WAKE_PIN, HIGH);

  return true;
}


byte CCS811::readStatus(void)
{
  digitalWrite(_WAKE_PIN, LOW);
  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(STATUS);
  Wire.endTransmission();

  Wire.requestFrom(_I2C_ADDR, (uint8_t)1);
  byte status;
  if(Wire.available() == 1)
    status = Wire.read();

  digitalWrite(_WAKE_PIN, HIGH);
  return status;
}

byte CCS811::readMeasure(void)
{
  digitalWrite(_WAKE_PIN, LOW);
  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(MEAS_MODE);
  Wire.endTransmission();

  Wire.requestFrom(_I2C_ADDR, (uint8_t)1);
  //byte MEAS_MODE = Wire.read();
  byte _meas;
  if(Wire.available() == 1)
    _meas = Wire.read();

  digitalWrite(_WAKE_PIN, HIGH);
  return _meas;
}


byte CCS811::readHW_ID(void)
{
  digitalWrite(_WAKE_PIN, LOW);
  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(HW_ID);
  Wire.endTransmission();

  Wire.requestFrom(_I2C_ADDR, (uint8_t)1);
  byte hw_id = Wire.read();

  digitalWrite(_WAKE_PIN, HIGH);
  return hw_id;
}


byte CCS811::readErrorID(byte _status)
{
  digitalWrite(_WAKE_PIN, LOW);
  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(ERROR_ID);
  Wire.endTransmission();

  Wire.requestFrom(_I2C_ADDR, (uint8_t)1);
  byte error_id = Wire.read();

  digitalWrite(_WAKE_PIN, HIGH);
  uint8_t bit = (_status & (1 << 1-1)) != 0; // black magic to read ERROR bit from STATUS register
  if(bit == 1)
  {
    Serial.print("Error ID: ");
    Serial.println(error_id);
  }

  return error_id;
}


void CCS811::sleep()
{
  digitalWrite(_WAKE_PIN, LOW);
  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(MEAS_MODE);
  Wire.write(0x00000000);  // sets sensor to idle; measurements are disabled; lowest power mode
  Wire.endTransmission();
  digitalWrite(_WAKE_PIN, HIGH);  // set WAKE_PIN high - this puts sensor in sleep mode (~2uA) and all I2C communications are ignored
}


void CCS811::getData(void)
{
  //CCS811::compensate(t, rh);
  digitalWrite(_WAKE_PIN, LOW);
  delay(1000);

  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(ALG_RESULT_DATA);    // reading ALG_RESULT_DATA clears DATA_READY bit in 0x00
  Wire.endTransmission();

  Wire.requestFrom(_I2C_ADDR, (uint8_t)4);
  delay(1);
  int buffer[4];
  if(Wire.available() == 4)
  {
    for(int i=0; i<4; i++)
    {
      buffer[i] = Wire.read();
      //Serial.print(buffer[i]);
    }
  }
  CO2 = ((uint8_t)buffer[0] << 8) + buffer[1];
  TVOC = ((uint8_t)buffer[2] << 8) + buffer[3];

  digitalWrite(_WAKE_PIN, HIGH);
}


int CCS811::readTVOC(void)
{
  return TVOC;
}


int CCS811::readCO2(void)
{
  return CO2;
}


void CCS811::compensate(float t, float rh)    // compensate for temperature and relative humidity
{
  digitalWrite(_WAKE_PIN, LOW);

  int _temp, _rh;
  if(t>0)
    _temp = (int)t + 0.5;  // this will round off the floating point to the nearest integer value
  else if(t<0) // account for negative temperatures
    _temp = (int)t - 0.5;
  _temp = _temp + 25;  // temperature high byte is stored as T+25°C in the sensor's memory so the value of byte is positive
  _rh = (int)rh + 0.5;  // this will round off the floating point to the nearest integer value

  byte _ENV_DATA[4];

  _ENV_DATA[0] = _rh << 1;  // shift the binary number to left by 1. This is stored as a 7-bit value
  _ENV_DATA[1] = 0;  // most significant fractional bit. Using 0 here - gives us accuracy of +/-1%. Current firmware (2016) only supports fractional increments of 0.5
  _ENV_DATA[2] = _temp << 1;
  _ENV_DATA[3] = 0;

  Wire.beginTransmission(_I2C_ADDR);
  Wire.write(ENV_DATA);
  Wire.write(_ENV_DATA[0]); // 7 bit humidity value
  Wire.write(_ENV_DATA[1]);
  Wire.write(_ENV_DATA[2]);
  Wire.write(_ENV_DATA[3]);
  Wire.endTransmission();

  digitalWrite(_WAKE_PIN, HIGH);
}

LIB CCS811.h:

/***************************************************
  This is a library for the CCS811 digital TVOC/eCO2 Sensor by CCMOSS/AMS
  http://www.ccmoss.com/gas-sensors#CCS811

  October 28, 2016

  The sensor uses I2C protocol to communicate, and requires 2 pins - SDA and SCL
  Another GPIO is also required to assert the WAKE pin for communication. this
  pin is passed by an argument in the begin function.

  A breakout board is available: https://github.com/AKstudios/CCS811-Breakout

  The ADDR pin on the sensor can be connected to VCC to set the address as 0x5A.
  The ADDR pin on the sensor can be connected to GND to set the address as 0x5B.

  Written by Akram Ali from AKstudios (www.akstudios.com)
  GitHub: https://github.com/AKstudios/
  BSD license, all text above must be included in any redistribution
 ****************************************************/

#ifndef CCS811_h
#define CCS811_h

#if (ARDUINO >= 100)
 #include "Arduino.h"
#else
 #include "WProgram.h"  // to allow boolean and byte functions
#endif

#include "Wire.h"   // Wire library for I2C protocol

#define nWAKE           4      // pin 4 is tied to CCS811 nWAKE pin in sensor node
#define nINT            7      // pin 7 is tied to CCS811 nINT pin in sensor node

#define ADDR            0x5A   // when I2C_ADDR pin is LOW
//#define ADDR            0x5B   // when I2C_ADDR pin is HIGH

// Registers for CCS811
#define STATUS          0x00
#define MEAS_MODE       0x01
#define ALG_RESULT_DATA 0x02
#define ENV_DATA        0x05
#define APP_START       0xF4
#define HW_ID           0x20
#define ERROR_ID        0xE0
#define SW_RESET        0xFF

class CCS811
{
  public:
    CCS811();     // constructor
    boolean begin(uint8_t I2C_ADDR, uint8_t WAKE_PIN);
    byte readStatus(void);
    byte readMeasure(void);
    byte readHW_ID(void);
    int readTVOC(void);
    int readCO2(void);
    void getData(void);
    void compensate(float t, float rh);
    byte readErrorID(byte _status);
    void reset(void);
    void sleep();
    int TVOC, CO2;

  private:
    uint8_t _WAKE_PIN;
    uint8_t _I2C_ADDR;
};

#endif

[dreamy1]

Hallo Armin,

danke fürs Teilen!

Woher hast Du denn den CCS811? Ich traue den Dingern irgendwie (noch) nicht, die aktuell aus China kommen. Ist da irgendwas aufm Chip, was auf original AMS Chips hinweist?

[WagoKlemme]

Hallo Stefan,

meiner ist von hier. War in einer Woche da.
Ich würde aber in Zukunft lieber den von EXPtech /Sparkfun nehmen. Kostet zwar 34 Euros, aber dafür funktioniert auch die LIB von Sparkfun. Mit meinem von Ebay funktioniert die LIB nicht. Deshalb auch die o.g. LIB, die auch prompt einen Bug bei der Modeumschaltung hatte.
Ausserdem glaube ich, wie auch beim BME280, dass die Verarbeitung schon entscheidend ist. Und damit das Messergebnis. Deshalb habe ich einen BME280 von Sparkfun geordert und werde das mal überprüfen.

Edit: Aufm Chip steht 811B und ein kreisförmiges Logo. Genau wie auf dem Bild in Ebay.

[dreamy1]

Hmmm, den Sparkfun habe ich auch gesehen. Wenn bei einem die Lib funktioniert und beim anderen nicht, ist das kein gutes Zeichen...dann scheinen die Sensoren unterschiedlich zu sein (kenne ich von den Fake-NRF24L01 nur zu gut).

Aber mal ehrlich...bei 34€ kannst Du auch gleich den Core nehmen, der ist dann letztendlich kleiner und hat bereits eine Staubschutzkappe onboard. Ich bleibe jedenfalls erstmal beim Core P.

[WagoKlemme]

Das mit der Lib muss ich mir nochmal anschauen. Zuerst dachte ich der Sensor ist defekt und wollte einfach nur Werte angezeigt bekommen. Das ging eben mit der Sparkfun-Lib erstmal nicht. Vielleicht lags auch am Wakeup.

Ich halte, so nach 2 Tagen Beobachtung, auch erstmal am iAQ fest.